0 '·········· Consalvi Software ········
1 '·········· Il gioco dei dadi ········
10 CLS:DIMK(4)
20 LINE(20,3)-(219,60),1,B:PRINT@50," Il gioco dei dadi "
30 PRINT@127,"Premi (I) per le istruzioni
40 PRINT@210,"Premi (G) per giocare
60 I$=INKEY$:IFI$="I"THEN1000
80 IFI$="G"THEN100
90 GOTO60
100 X=16:Y=22:SC=10000:SD=10000
105 CLS:LINE(5,3)-(73,60),1,B:LINE(6,4)-(72,59),1,B:LINE(4,2)-(74,61),1,B:LINE(14,20)-(33,39),1,B:LINE(44,20)-(63,39),1,B
110 PRINT@45,"Dadi"
120 GOSUB560:X=X+30:GOSUB650:X=X-30
130 PRINT@18,"Il gioco dei dadi"
140 PRINT@94,"Il tuo nome ";:INPUTN$
145 IFLEN(N$)=0ORLEN(N$)>12THENBEEP:GOTO105
146 PRINT@102,"                ";
150 PRINT@94,"Olivetti M10 ";SD;"$     ";:PRINT@174,N$;:PRINT@187,SC;"$     ";
151 IFSC=0ORSD=0GOTO750
152 PRINT@254,"                   "
155 PRINT@254,"Quanto punti ";:INPUTSO
156 IFSO<100ORSO>SCORSO>SDTHENBEEP:GOTO155
157 PRINT@254,"                      "
159 PRINT@259,"Premi (spazio)"
160 I$=INKEY$:IFI$=" "THEN180
170 GOTO160
180 LINE(15,21)-(32,38),0,BF:LINE(45,21)-(62,38),0,BF
185 GOSUB400
190 PRINT@243,"I  tuoi"
200 BEEP:FORH=1TO2
210 ONK(H)GOSUB500,530,560,600,650,700
215 X=X+30:NEXTH
220 I$=INKEY$:IFI$=" "THEN240
230 GOTO220
240 X=X-60:LINE(15,21)-(32,38),0,BF:LINE(45,21)-(62,38),0,BF:BEEP:FORH=3TO4
250 PRINT@243,"I  miei";
260 ONK(H)GOSUB500,530,560,600,650,700
270 X=X+30:NEXTH
275 X=X-60
280 IF(K(1)+K(2))>(K(3)+K(4))THEN340
290 IF(K(1)+K(2))=(K(3)+K(4))THEN390
300 BEEP:PRINT@259,"Ho vinto io ! ";:SD=SD+SO:SC=SC-SO:FORI=1TO1000:NEXT:GOTO150
340 SOUND4000,20:PRINT@259,"Hai vinto tu !";:SC=SC+SO:SD=SD-SO:FORI=1TO1000:NEXT:GOTO150
390 BEEP:BEEP:PRINT@259,"    Pari !    ";:FORI=1TO1000:NEXT:GOTO150
400 '********* NUMERI CASUALI *********
410 G=VAL(RIGHT$(TIME$,2))/2
420 IFG>18THENG=INT(G/2)
430 FORJ=1TO4
440 FORT=1TOG
450 K(J)=INT(RND(1)*6)+1
460 NEXTT
470 NEXTJ
480 RETURN
500 LINE(X+6,Y+6)-(X+9,Y+9),1,B
510 RETURN
530 LINE(X,Y)-(X+3,Y+3),1,B:LINE(X+12,Y+12)-(X+15,Y+15),1,B
540 RETURN
560 LINE(X,Y)-(X+3,Y+3),1,B:LINE(X+12,Y+12)-(X+15,Y+15),1,B:LINE(X+6,Y+6)-(X+9,Y+9),1,B
570 RETURN
600 LINE(X,Y)-(X+3,Y+3),1,B:LINE(X+12,Y+12)-(X+15,Y+15),1,B:LINE(X+12,Y)-(X+15,Y+3),1,B:LINE(X,Y+12)-(X+3,Y+15),1,B
610 RETURN
650 LINE(X,Y)-(X+3,Y+3),1,B:LINE(X+12,Y+12)-(X+15,Y+15),1,B:LINE(X+12,Y)-(X+15,Y+3),1,B:LINE(X,Y+12)-(X+3,Y+15),1,B:LINE(X+6,Y+6)-(X+9,Y+9),1,B
660 RETURN
700 LINE(X,Y)-(X+3,Y+3),1,B:LINE(X+6,Y)-(X+9,Y+3),1,B:LINE(X+12,Y)-(X+15,Y+3),1,B
710 LINE(X,Y+6)-(X+3,Y+9),1,B:LINE(X+6,Y+6)-(X+9,Y+9),1,B:LINE(X+12,Y+6)-(X+15,Y+9),1,B
720 LINE(X,Y+12)-(X+3,Y+15),1,B:LINE(X+6,Y+12)-(X+9,Y+15),1,B:LINE(X+12,Y+12)-(X+15,Y+15),1,B
730 RETURN
750 IFSC<SDTHENPRINT@243,"Ho vinto";
760 IFSD<SCTHENPRINT@242,"Hai vinto";
770 PRINT@254," Vuoi continuare ? (s/n)";
780 I$=INKEY$:IFI$="S"THEN100
790 IFI$="N"THENMENU
795 GOTO780
1000 CLS:PRINT"Devi cercare di battermi realizzando  un"
1010 PRINT"punteggio pi` alto del mio con i dadi.Se"
1020 PRINT"ci riesci vinci la puntata e io la perdo"
1030 PRINT@252,"Premi un tasto ..."
1040 I$=INKEY$:IFI$=""THEN1040
1050 GOTO100