5 '·· RENUM by Consalvi Software ·······
10 '
20 CLS:LINE(32,5)-(207,18),1,BF
30 PRINTCHR$(27)+"p";:PRINT@56,"RENUMBER";:PRINTCHR$(27)+"q"
40 LINE(29,2)-(210,21),1,B
50 PRINT@210,"by Consalvi Software"
60 FORH=1TO1500:NEXT
70 CLEAR500
80 GOSUB990
90 CLEAR500:IFMAXFILES<1THENMF=1:MAXFILES=1ELSEMF=0
100 LINE(0,0)-(239,63),1,B:PRINTCHR$(27)+"p";:PRINT@15," RENUMBER ";:PRINTCHR$(27)+"q";
110 PRINT@81,"File da rinumerare   ";:INPUTF$
120 IFF$=""THENCLS:GOTO100
140 PRINT@161,"Nuova prima linea   ";:GOSUB1120:N=VAL(R$)
160 PRINT@241,"Incremento di linea  ";:GOSUB1120:L=VAL(R$)
170 IFL<=0THENL=10
180 IFN<0THENN=0
190 ONERRORGOTO1210
200 OPENF$FORINPUTAS1:I=1
210 CLS:PRINT@132,"Fase di RENUMBER"
220 LINEINPUT#1,A$
230 A=A+LEN(A$)
240 IFEOF(1)THEN260
250 I=I+1:GOTO220
260 CLOSE1
270 OPEN"I.DO"FOROUTPUTAS1
280 PRINT#1,I,N,L,MF,F$
290 CLOSE1
300 CLEARA+300
310 OPEN"I.DO"FORINPUTAS1
320 INPUT#1,I,N,L,MF,F$
330 CLOSE1
340 KILL"I.DO"
350 DIMA$(I),B$(I)
360 OPENF$FORINPUTAS1
370 FORJ=1TOI:LINEINPUT#1,A$(J):NEXTJ
380 CLOSE1
390 FORJ=1TOI:FORK=1TOLEN(A$(J))
400 S$=LEFT$(A$(J),1)
410 IFASC(S$)<58ANDASC(S$)>47THENB$(J)=B$(J)+S$:A$(J)=RIGHT$(A$(J),LEN(A$(J))-1)ELSENEXTJ
420 IFJ>ITHEN440
430 NEXTK:NEXTJ
440 FORJ=1TOI:S$="":FO=0:FORK=1TOLEN(A$(J))+253
450 IFK=LEN(A$(J))THEN590
460 IFMID$(A$(J),K,1)="'"ANDFO=0THEN590
470 IFMID$(A$(J),K,1)=" "THEN580
480 IFMID$(A$(J),K,1)=CHR$(34)ANDFO=0THENFO=1:GOTO580
490 IFMID$(A$(J),K,1)=CHR$(34)ANDFO=1THENFO=0:GOTO580
500 IFFO=1THEN580
510 S$=S$+MID$(A$(J),K,1):S$=RIGHT$(S$,4)
520 IFRIGHT$(S$,3)="REM"ANDFO=0THEN590
530 IFS$="DATA"ANDFO=0THEN590
540 IFS$="GOTO"ORS$="THEN"ORS$="ELSE"ORS$="OSUB"ORS$="SUME"ORS$="TORE"THENK1=0:GOSUB660
550 IFRIGHT$(S$,3)="RUN"THENK1=0:GOSUB660
560 IFS$="EDIT"ORS$="LIST"THENK1=0:GOSUB660
570 IFS$="LETE"THENK1=0:GOSUB660
580 NEXTK
590 NEXTJ
600 OPENF$FOROUTPUTAS1
610 FORJ=1TOI
620 PRINT#1,RIGHT$(STR$(J*L+N-L),LEN(STR$(J*L+N-L))-1);A$(J)
630 NEXTJ
640 CLOSE#1
650 BEEP:IFMF=1THENMAXFILES=0:MENUELSEMENU
660 IFK+1>LEN(A$(J))THENRETURNELSEIFK1=0THENK1=K+1ELSEK1=K1+1
670 IFK1>LEN(A$(J))THENPRINT"Errore in linea ";B$(J):RETURN
680 S$=MID$(A$(J),K1,1)
690 IFS$=" "ANDK1+1>LEN(A$(J))THEN910
700 IFS$=" "THEN660
710 IFS$=","ANDMID$(A$(J),K1-1,1)=","THENK=K1:GOTO660
720 IFS$=","THEN810
730 IFS$="-"THEN860
740 IFASC(S$)<=47ORASC(S$)>=58THEN780
750 IFASC(S$)>47ANDASC(S$)<58THENZ$=Z$+S$
760 IFK1=LEN(A$(J))THEN910
770 GOTO660
780 IFZ$=""THENS$="":RETURN
790 GOSUB940
800 A$(J)=LEFT$(A$(J),K)+Z$+RIGHT$(A$(J),LEN(A$(J))-K1+1):K=K+LEN(Z$):Z$="":RETURN
810 IFZ$=""THENS$="":GOTO660
820 GOSUB940
830 A$=LEFT$(A$(J),K)+Z$+","+RIGHT$(A$(J),LEN(A$(J))-K1)
840 K=K+LEN(Z$)+1:Z$="":S$="":K1=0
850 A$(J)=A$:GOTO660
860 IFZ$=""THENS$="":RETURN
870 GOSUB940
880 A$=LEFT$(A$(J),K+Z$+"-"+RIGHT$(A$(J),LEN(A$(J))-K1)
890 K=K+LEN(Z$)+1:Z$="":S$="":K1=0
900 A$(J)=A$:GOTO660
910 IFZ$=""THENK=K1:RETURN
920 GOSUB940
930 A$(J)=LEFT$(A$(J),K)+Z$:Z$="":RETURN
940 FORM=1TOI:IFVAL(Z$)=VAL(B$(M))THENZ$=RIGHT$(STR$(M*L+N-L),LEN(STR$(M*L+N-L))-1):GOTO980
950 NEXTM
960 PRINT:PRINT"Errore in nuova linea ";J*L+N-L
970 PRINT"(Vecchia linea ";B$(J);"); Linea ";Z$;" non trovta "
980 RETURN
990 CLS
1000 '
1010 A=65024
1020 FORJ=1TO8
1030 B=PEEK(A+I)
1040 C$(J)=C$(J)+CHR$(B)
1050 NEXTJ
1060 FORJ=1TO8
1070 D=INSTR(1,C$(J),"I     .DO"):IFD<>0THEN1100
1080 NEXTJ
1090 RETURN
1100 SOUND2000,100:PRINT:PRINT"Rinominare file I.DO altrimenti":PRINT"si cancella !"
1110 MENU
1120 INPUTR$
1130 IFR$=""THEN1190
1140 FORM=1TOLEN(R$)
1150 M$=MID$(R$,M,1)
1160 IFASC(M$)<48ORASC(M$)>57THEN1190
1170 NEXTM
1180 RETURN
1190 '
1200 GOTO140
1210 BEEP:IFERR<>52THENRESUME70
1220 GOTO10